数字だけで日付を入力する

-------------------
スクリプト名「FieldSet_日付変換4or8_Ftrg」
-------------------
#設定：変換したい日付フィールドに
　　　スクリプトトリガ「OnObjectValidate」としてこのスクリプトを設定。
#目的：数字で入力された値を日付に変換。月日入力の場合は当年を年に設定。
　　　入力は8桁または4桁数字入力後、スクリプトトリガでyyyy/mm/ddに変換。
#条件：FM12以降（11以前のバージョンでは未確認）
#
エラー処理 [ オン ]
変数を設定 [ $Str; 値:Get ( アクティブフィールド内容 ) ]
変数を設定 [ $FieldName; 値:Get ( アクティブフィールドテーブル名 ) & "::" & Get ( アクティブフィールド名 ) ]
If [ IsEmpty ( $Str ) ]
　#空欄の場合
　フィールドを名前で設定 [ $FieldName; GetAsDate ( "" ) ]
　現在のスクリプト終了 [ 結果: 0 ]
Else If [ PatternCount ( $Str ; "/" ) = 1 or PatternCount ( $Str ; "/" ) = 2 ]
　#日付指定している場合
Else If [ Length ( $Str ) = 4 or Length ( $Str ) = 8 ]
　#4桁、8桁の場合
　変数を設定 [ $Year; 値:Case (Length ( $Str ) = 4 ; Year ( Get ( 日付 ) ) ; Length ( $Str ) = 8 ; Left ( $Str ; 4 ) ;"" ) ]
　変数を設定 [ $Month; 値:Case (Length ( $Str ) = 4 ; Left ( $Str ; 2 ) ; Length ( $Str ) = 8 ;Middle ( $Str ; 5 ; 2 ) ; "" ) ]
　変数を設定 [ $Day; 値:Case (Length ( $Str ) = 4 ; Right ( $Str ; 2 ) ; Length ( $Str ) = 8 ;Middle ( $Str ; 7 ; 2 ) ; "" ) ]
　フィールドを名前で設定 [ $FieldName; Date ( $Month ; $Day ; $Year ) ]
　If [ $Year = "0000" or $Year > 4001 ]
　　フィールドを名前で設定 [ $FieldName; GetAsDate ( "" ) ]
　　カスタムダイアログを表示 [ タイトル: "日付入力"; メッセージ: "FileMakerでは設定できない日付です";
　　　　　　　　　　　　　　　デフォルトボタン: 　「OK」, 確定: 「はい」 ]
　　現在のスクリプト終了 [ 結果: 0 ]
　Else If [ ($Year = 4000 and $Month > 12) or
　　　　　($Year = 4000 and $Month = 12 and $Day > 31) ]
　　フィールドを名前で設定 [ $FieldName; GetAsDate ( "" ) ]
　　カスタムダイアログを表示 [ タイトル: "日付入力"; メッセージ: "FileMakerでは設定できない日付です";
　　　　　　　　　　　　　　　デフォルトボタン: 　「OK」, 確定: 「はい」 ]
　　現在のスクリプト終了 [ 結果: 0 ]
　End If
Else
　カスタムダイアログを表示 [ タイトル: "日付入力"; メッセージ: "数字だけで指定する場合は、
　　　　　　　　　　　　　　¶4桁または8桁で指定してくだ さい";
　　　　　　　　　　　　　　デフォルトボタン: 「OK」, 確定: 「はい」 ]
　現在のスクリプト終了 [ 結果: 0 ]
End If
-------------------